交易指令进阶

2013年4月23日 (二) 22:54的版本

金魔方智能交易攻略（2）-交易指令进阶

作者：仁心慧能

以多头开平仓函数为例：

Buy('Symbol'=,Size=DEFAULT,Price=0,Slippage=0,OT=OT_MARKET,OB=OB_NEXTBAR,EntryName=)

Sell('Symbol'=,Size=DEFAULT,Price=0,Slippage=-1,OT=OT_MARKET,OB=OB_NEXTBAR,ExitName=)<from 'EntryName'>

括号里面表示函数的参数，之所以见到有赋值，表示如果不写这个参数，其默认值为等号后面的值，实际应用时填入需要指定的值，而不是写赋值语句。

例如：

Buy; 等价于 Buy(, DEFAULT, 0, 0,OT_Market, OB_NextBar, );

Buy(,2); 等价于 Buy(, 2, 0, 0,OT_Market, OB_NextBar, );

Buy(,2, 0,1); 等价于 Buy(, 2, 0, 1,OT_Market, OB_NextBar, );

Buy(,2, 1000,0,OT_LIMIT); 等价于 Buy(, 2, 1000, 0,OT_LIMIT, OB_NextBar, );

也就是说，如果你不写从后到前的参数，系统会自动替你填进那些参数，怎么填呢？

就是格式中等号后面的那些值。

平仓函数后有尖括号括起来的<from 'EntryName'>，表示这是可选的，需要用到时才写。

这类函数可以设置交易商品、委托类型、时机、数量、价格、滑移价差，还可以指定一个开仓名EntryName，

用于标识不同的交易信号所开的仓，以及今后的单独控制；平仓函数则可指定一个平仓名ExitName，

并且用from 表示平其中某种信号开的仓。

函数的参量后若有等号，表示等号后的值是默认值，这样的参数按照从后到前的顺序，可以省略不写。

省略所有参数的交易指令，其委托数量是取用【策略设置】中的数值，可以为固定数量，也可以由资金自动计算下单量。

缺省的交易时机和类型是次周期(OB_NEXTBAR)市价单(OT_MARKET)，市价单是要求立即成交的委托单，

次周期市价单在历史测评时以下一周期的开盘价作为委托成交价，在实际交易中以周期开始时的市价下单，

委托价格一般在买入时为卖一价，卖出时为买一价，有时再加减允许的滑移价差，以保证立即成交。

更详细的参数说明可参看公式编辑器里的函数说明，我们还是多做些实验吧。

   //-------金魔方智能交易公式--------------
   //例2_1 一目均衡多空策略
   {策略：
   1.转换线金叉基准线，本周期收盘时平空反手做多
   2.转换线死叉基准线，本周期收盘时平多反手做空
   3.多头自开仓20周期后平仓
   }
   input:
     SN(26), FN(9);
   基准线: (HHV(H,SN)+LLV(L,SN))/2;
   转换线: (HHV(H,FN)+LLV(L,FN))/2;
   bEnterLong := CrossOver(转换线, 基准线);
   bEnterShort := CrossUnder(转换线, 基准线);
   if bEnterLong then Buy(, DEFAULT, 0, 0, OT_CLOSE, OB_THISBAR);
   if bEnterShort then SellShort (, DEFAULT, 0, 0, OT_CLOSE, OB_THISBAR);
   if BarsSinceEntry(0) >= 20 then Sell;
   if BarsSinceEntry(0) >= 20 then BuyToCover;
   {
   注解:
   1.CrossOver函数等同于Cross函数
   2.开仓DEFAULT指定的下单量为[策略设置]中的委托数量
     平仓函数里的DEFAULT表示全部平仓
   3.OT_CLOSE 与 OB_THISBAR 配合指定本周期收盘时交易，历史回测时以本周期收盘价作为成交价格，
      实盘自动交易时，对于分钟线周期，其实是在本周期结束，下一周期开始时下市价单的，
      对于日线周期，或者对于分钟线当天收盘的最后一个周期，
      则下单时机在[策略设置]-[自动交易]中的“日收盘交易在(n)秒前下单”指定。
   }

有图有真相：

对于例1_3的布林通道振荡策略，若想在价格达到上下轨或均线时下单，公式如下：

   //-------金魔方智能交易公式--------------
   //例2_2  布林通道振荡策略之二
   {策略：
   1.价格跌至下轨时开多，价格升至中线时平多
   2.价格升至上轨时开空，价格跌至中线时平空
   }
   input:
     M(20,5,200,5), N(2), S(3);
   Mid :  MA(C,M);
   Upper: Mid + N*STD(C,M),Shift1;
   Lower: Mid - N*STD(C,M),Shift1;
   Buy(, 1, Lower, 0, OT_LIMIT);
   Sell(, 1, Mid, 0, OT_LIMIT);
   SellShort(, 1, Upper, 0, OT_LIMIT,OB_NEXTBAR);
   BuyToCover(, 1, Mid, 0, OT_LIMIT,OB_NEXTBAR);
   {
   注解：
   1.Shift1 使指标线向右偏移1个周期，使得它显示时与NEXTBAR的交易时机对上。
   }

有图有真相：

如图所示，当价格跌到前周期的下轨值时买入，然后价格达到前周期的均线值时卖出，

因本周期未结束时，指标值是不定的，所以我们用上一周期的指标值，那么，交易指令的OB参数还是OB_NEXTBAR，

可省略，表示在下一周期用本周期的指标值下单，下单类型为OT_LIMIT限价单，限定价格Price参数为布林线下轨Lower等指标值。

这个策略在行情盘整时看起来不错，但在趋势行情时会亏损，那么，我们再来个反向操作策略，并且把布林通道改为肯特纳(Keltner)通道，

公式如下：

   //-------金魔方智能交易公式--------------
   //例2_3  肯特纳(Keltner)通道趋势策略
   {策略：
   1.价格升破上轨时开多，价格跌至中线时平多
   2.价格跌破下轨时开空，价格升至中线时平空
   }
   input:
     M(20,5,200,5), N(2);
   Mid :  EMA(C,M);
   Upper: Mid + N*ATR(10),Shift1;
   Lower: Mid - N*ATR(10),Shift1;
   Comment('突破买入价: ', Upper[1]:8:2), ColorRed;
   Comment('突破卖空价: ', Lower[1]:8:2), ColorBlue;
   Buy(, 2, Upper+MinDiff, -1, OT_STOP);
   Sell(, DEFAULT, Mid, -1, OT_STOP);
   SellShort(, 2, Lower-MinDiff, -1, OT_STOP);
   BuyToCover(, DEFAULT, Mid, -1, OT_STOP);
   {
   注解：
   1.ATR(10)为10周期平均真实波幅，均线加减ATR倍数即形成肯特纳(Keltner)通道
   2.Comment('突破买入价: ', Upper[1]:8:2)在主图左上角显示提示信息，
     此处指定输出的数字串为8个字符长度，带2位小数;可以指定颜色
   3.平仓函数委托数量为DEFAULT表示全部平仓
   }

运行结果如下图：

如图所示，这次的开平仓正好和前例是反着的，因为下单类型为OT_STOP停损单，它与限价单正好是相反的，

当我们要买入时，限价单是埋在当前市价的下方，等待价格下跌到限价时成交，而停损单是在当前市价的上方，

等待价格向上突破时成交。卖出时方向相反。对于停损单这个术语，卖出停损容易明白，对于买入开仓，

可以这样理解，因为我是要买入的，价格在不断往上行，少赚也是一种亏损，所以在价格升到一定位置时买入“停损”。

需要注意的是，停损价之后的Slippage参数都被设为-1，这表示只要价格突破停损价就交易，例如次日跳空高开，

不管多高都要买入。如果要限制交易价格，太高了就不买入，那就设置Slippage参数为允许的范围，这种单叫做停损限价单，

请自行修改测试。

这次我们在公式的交易指令函数中指定委托数量为2，可以把鼠标移到交易箭头处或查看测评报告中的交易明细。

以上的趋势和振荡策略实例在贴图中都用于日线周期，自动交易常用于日内交易，这类公式有些什么特殊的编制技巧呢？

且听下回分解！