指标背离交易及风险控制策略

2013年4月23日 (二) 23:13的版本

金魔方智能交易攻略（5）-指标背离交易及风险控制策略

作者：仁心慧能

缠论等交易理论重视指标背离时的交易信号，请看金魔方公式如何实现：

   //-------金魔方智能交易公式--------------
   //例5_1 指标背离买入风险控制策略
   {策略:
   1、RSI指标上穿25且与价格形成底背离时买入，不采用指标平仓，而是
   2、综合运用止盈、止损、保本平仓、跟踪止损、盘整平仓等风险控制技术
   }
   input:
     波谷强度(3),//用于找波谷并判断背离
     止损价差(35),
     止赢价差(100),
     保本启动价差(20),
     跟踪启动价差(30),
     跟踪回撤价差(20),
     跟踪回撤幅度(20),
     盘整最大价差(5),
     盘整周期数(5),
     使用价差(1), //开关控制使用价差或金额参数
     止损金额(10000),
     止赢金额(30000),
     保本启动金额(6000),
     跟踪启动金额(9000),
     跟踪回撤金额(6000);
     //计算RSI指标
   RSI1 : SMA(Max(C-C[1],0),8,1)/SMA(Abs(C-C[1]),8,1)*100, OwnerScale;
   底背离: Divergence(C,RSI1,波谷强度,30,-1), LineThick0;
   
   //若指标与价格走势发生牛背离，则在指标上穿25时买入
   if 底背离 and CrossOver(RSI1,25) then Buy;
   
   if 使用价差 = 1 then begin
     SetStopContract;  //以下风控金额基于单口计算
     if 止损价差 > 0 then
       SetStopLoss(止损价差*BigPointValue);
     if 止赢价差 > 0 then
       SetProfitTarget(止赢价差*BigPointValue);
     if 保本启动价差 > 0 then
       SetBreakEven(保本启动价差*BigPointValue);
     if 跟踪启动价差 > 0 And 跟踪回撤价差 > 0 then
       SetDollarTrailing(跟踪回撤价差*BigPointValue,跟踪启动价差*BigPointValue);
     if 跟踪启动价差 > 0 And 跟踪回撤幅度 > 0 then
       SetPercentTrailing(跟踪启动价差*BigPointValue,跟踪回撤幅度);
     if 盘整最大价差 > 0 And 盘整周期数 > 0 then
       SetInactive(盘整最大价差*BigPointValue,盘整周期数);
   end
   else begin
     SetStopPosition;  //整个仓位的止损止盈金额
     if 止损金额 > 0 then
       SetStopLoss(止损金额);
     if 止赢金额 > 0 then
       SetProfitTarget(止赢金额);
     if 保本启动金额 > 0 then
       SetBreakEven(保本启动金额);
     if 跟踪启动金额 > 0 And 跟踪回撤金额 > 0 then
       SetDollarTrailing(跟踪回撤金额,跟踪启动金额);
     if 跟踪启动金额 > 0 And 跟踪回撤幅度 > 0 then
       SetPercentTrailing(跟踪启动金额,跟踪回撤幅度);
   end
   {
   注解：
   1.OwnerScale修饰符可以使RSI指标叠加在主图上
   2.LineThick0修饰符用于查看底背离状态而不画出指标线
   3.Divergence函数可用于判断指标与价格走势的背离，
     波谷点是前后各N个周期的相对低点，这个N即为波谷强度
     最后一个参数为1表示判断顶背离（熊背离），为-1表示判断底背离（牛背离）
   }

有图有真相：

可以看到，在买入前，RSI指标与价格走势发生了背离，当RSI上穿25时，发出买入指令，之后止盈平仓。

之前介绍的都是指标交易策略，金魔方能否实现形态交易呢？比如趋势线交易？

SetStopLoss之类的函数实现了经典的风险控制技巧，它们在满足条件时都是全部清仓的。

我们怎样通过Sell/BuyToCover平仓函数和一些交易状态函数实现更灵活的控制？

且听下回分解！